#! /bin/tcsh
# Rimon's .aliases file
# Last change: 2006 Oct 13
# Download latest from:
#   http://rimonbarr.com/repository/files/.aliases
# Comments and suggestions to: barr+files@cs.cornell.edu

# shortcuts
alias aliases 'source ~/.aliases'
alias .       'source'
alias ,       'ls'
alias k9      'kill -9'
alias kup     'kill -HUP'
alias h       history
alias c       clear
alias j       'jobs -l'
alias l       less -iq
alias x       'xterm &'
alias f       finger
alias fc      'finger \!*@cornell.edu'

# dir
alias md 'mkdir'
alias rd 'rmdir'
alias mdcd 'md \!*; cd \!*'
alias mcd 'mdcd'
alias cd.. 'cd ..'
alias .. 'cd ..'
alias ... 'cd ../..'
alias .... 'cd ../../..'
alias ..... 'cd ../../../..'
if ( ${TERM} == "vt100" || ${TERM} == "vt102" || ${HOSTTYPE} == "sun4" ) then
  alias ls 'ls -CF'
  alias ll 'ls -CFlh'
  alias la 'ls -CFA'
  alias lla 'ls -CFlAh'
else
  alias ls 'ls -CF --color=tty'
  alias ll 'ls -CFlh --color=tty'
  alias la 'ls -CFA --color=tty'
  alias lla 'ls -CFlAh --color=tty'
endif
alias dir ll
alias d dir
alias big 'ls -l | sort -r -k5 -n | more'
alias dusort 'du -s * | sort -nr'
alias bc 'bc -l'

# dos
alias cls 'clear'
alias del 'rm -i'
alias copy 'cp'
alias ren 'mv'
alias move 'mv'
alias dos2unix 'sed s/^M//g'
alias unix2dos 'sed s/\$/^M/'
alias removecontrols 'sed "s/.//g"'

# vi
if ( $?DISPLAY ) then
  alias v gvim
  alias vi gvim
  alias Vi xterm -title "'Vi:\!^'" -geometry 80x65 -e vi \!\* \&
  alias view xterm -title "'View:\!^'" -geometry 80x35 -e view \!\* \&
  alias View xterm -title "'View:\!^'" -geometry 80x65 -e view \!\* \&
else
  alias vi vim -X
  alias v vim -X
endif
alias vim vim -X

# apps
alias xterm 'xterm -cm -cr black -fg black -bg BlanchedAlmond'
alias kgv 'kghostview \!* &'
alias k 'konqueror \!* >& /dev/null &'
alias ar 'acroread'
alias mc 'setenv MC `/usr/bin/mc -P \!*`; cd $MC; unsetenv MC'
alias xdvi 'xdvi -keep -expert -bg beige -interpreter /usr/bin/gs -nogssafer'
alias matlabrim matlab -nosplash -nodesktop
alias limewire "pushd ${HOME}/bin/limewire >& /dev/null; ./runLime.sh; popd >& /dev/null; rm -f /mp3/Incomplete/*"
alias explorer 'konqueror . >& /dev/null &'
alias start 'explorer'
alias xfig 'xfig -specialtext -latexfonts -startlatexFont default'
alias mpg 'mplayer -ao sdl -vo x11 -zoom -fs -really-quiet \!* >& /dev/null'

# ssh
alias ssh1 'ssh -1'
alias scp1 'scp -o Protocol=1'

# python
alias py 'python'
alias pyprof 'python /usr/lib/python2.3/profile.py'
alias ipy 'ipython -nobanner -noconfirm_exit -pprint'
alias kpy 'killall python'
alias kpy9 'killall -9 python'

# java
alias java 'java -cp ${CLASSPATH}:.'
alias javac 'javac -source 1.4'
alias kj 'killall java'
alias kj9 'killall -9 java'
alias prettyj java -cp /home/barr/bin/jbeautfull.jar com.stevesoft.jbeaut.JavaBeautifier -tab=2 -braces=NextLine
alias dejavac 'java mocha.Decompiler'

# printing
alias 2c 'enscript -g -G -2r -h -j -p -'
alias 2p 'psnup -2 -q'
alias 4p 'psnup -4 -q'
alias lprpdf 'cat \!* | acroread -toPostScript -shrink | lpr'
alias lprdvi 'dvips -t letter'
alias dvidit 'xdvi \!* & gvim \!*.tex'
alias pdfdit 'xpdf \!*.pdf & gvim \!*.tex'

# machines
alias rimbase 'ssh-to rimbase.rimonbarr.com'
alias sf 'ssh -1 -x batripler@shell.sourceforge.net'
alias andromeda 'ssh -p 60022 sm1-28.cise.ufl.edu'

# hebrew
alias hebterm     "xterm -fn heb8x13"
alias hebkeys     "xmodmap ~/.Xkeyboard.heb"
alias hebnormkeys "xmodmap ~/.Xkeyboard.pc"

# ethernet
alias eth0up 'su -- ifup eth0'
alias eth0down 'su -- ifdown eth0'
alias upeth0 'eth0up'
alias downeth0 'eth0down'
alias eth1up 'su -- ifup eth1'
alias eth1down 'su -- ifdown eth1'
alias upeth1 'eth1up'
alias downeth1 'eth1down'

# apache
alias hthup 'su -- /usr/sbin/apachectl restart'
alias htconf 'vim /etc/httpd/conf/httpd.conf'
alias htlog 'tail -f /etc/httpd/logs/error_log'

## pine
alias pinelocal '\pine -p ~/.pine.default -x ~/.pine.local'
alias pineremote '\pine -p ~/.pine.default -x ~/.pine.remote'
set HOSTNAME = `hostname`
if ( $?HOSTNAME ) then
	if ( $HOSTNAME =~ pompom* ) then
		alias pine pinelocal
	else if ( $HOSTNAME =~ rimbase* ) then
		alias pine pinelocal
	else if ( $HOSTNAME =~ jist* ) then
		alias pine pinelocal
	else
		alias pine pineremote
	endif
endif
alias p 'pine'
alias pinefilter '\pine -p ~/.pine.default -x .pine.filter' -d 0
alias filter '\pine -p ~/.pine.default -x .pine.filter -I q >& /dev/null'
alias rimpine '\pine -p ~/.pine.rimap'

# sync mail
alias syncmailquick 'rimap -s=5000 local fm quick'
alias syncmailspam  'rimap local fm spam'
alias syncmailquickspam  'rimap local fm quickspam'
alias syncmailimpt  'rimap local fm impt'
alias syncmail      'rimap local fm all'
alias smi 'syncmailimpt'
alias smq 'syncmailquick'
alias sms 'syncmailspam'
alias smqs 'syncmailquickspam'
alias sm  'syncmail'
alias dospam rimspam --user=rimonbarr --server imap.fusemail.com --ssl --size=50 --folder-good=INBOX.xunlearn --folder-bad=INBOX.xlearn --folder-spam=INBOX.xspam --folder-maybe=INBOX.xmaybe

# sync files
set unisonbatchflags="-contactquietly -xferbycopying -batch -ui text -terse -sortbysize"
alias srimbase 'unison rimbase'
alias sbrimbase srimbase $unisonbatchflags
alias swin 'unison win -fastcheck "*"'
alias sbwin swin $unisonbatchflags
alias sjist 'unison jist'
alias sbjist sjist $unisonbatchflags

# shutdown
#alias off 'su -- shutdown -h now'
alias restart 'su -- shutdown -r now'

# make
alias remake 'make clean; make'
alias clean 'make clean'
alias ctags 'ctags --langmap=c:+.pc --recurse --totals'

# www
alias websuck 'wget --recursive --level=inf --convert-links --no-parent --timestamping'
alias websuck1 'wget --recursive --level=1 --convert-links --no-parent --timestamping'
alias wwwhead 'lynx --source -head'
alias googlecache '/usr/local/netscape/netscape -P barr "http://www.google.com/search?q=cache:\!*"'
alias pollen 'lynx -dump http://weather.yahoo.com/graphics/pollen//east_usa_pollen.jpg > /tmp/pollen.jpg; xv /tmp/pollen.jpg'
alias startbatch 'ncftpbatch -d'
alias stopbatch 'killall ncftpbatch'

# tar
alias tarball 'tar -cvzf \!^.tgz \!^'
alias tarballx 'tarball \!^ && rm -rf \!^'

# job control
alias myproc 'ps aux | grep ${USER}'
alias mylogin 'who | grep ${USER}'
alias who 'who -uH'
alias ktop 'konsole -e top >& /dev/null &'
alias load 'cat /proc/loadavg'

# man
alias psman 'man -t'
alias kman 'konsole -e man \!* >& /dev/null &'

# calendar
alias calr 'cal `date | cut -d \  -f 7`'
alias cal "echo; date; echo; 'cal' -m3"

# vnc
alias rimvncserver 'vncserver :5 -name rimon -geometry 1024x768 -depth 16'
alias rimvnckill 'vncserver -kill :5'
alias rimvnc 'vncviewer glenlivet:5'

# misc utils / commands
alias passwd2addr 'sed "s/^\([^:]*\):.[^:]*:[^:]*:[^:]*:\([^:,]*\).*/\1	\2	\1@cs.cornell.edu/"'
alias nukefile 'echo -n "" >'
alias restartbatch 'killall ncftpbatch; sleep 1; ncftpbatch -d'
alias ccd 'mount /mnt/cdrom; cd /mnt/cdrom'
alias swap     'mv \!:1 __TMP__.$$ && mv \!:2 \!:1 ; mv __TMP__.$$ \!:2'
alias rdiff diff -crN

if ( -e ${HOME}/.aliases.local && -r ${HOME}/.aliases.local) then
  source ${HOME}/.aliases.local
endif